version = '0.1.0'
base.archivesName = 'saltatory-client'

repositories {
    maven {
        url = 'https://maven.ftb.dev/releases'
        content { includeGroup 'dev.ftb.mods' }
    }
    maven {
        url = 'https://api.modrinth.com/maven'
        content { includeGroup 'maven.modrinth' }
    }
}

configurations {
    createBundle
    testImplementation.extendsFrom compileOnly
}

def createLibs = tasks.register('createLibs', Sync) {
    from { zipTree(configurations.createBundle.singleFile) }
    include 'META-INF/jarjar/ponder-*.jar', 'META-INF/jarjar/flywheel-*.jar'
    into layout.buildDirectory.dir('create-libs')
}

dependencies {
    compileOnly('dev.ftb.mods:ftb-library-neoforge:2101.1.37') { transitive = false }
    createBundle('maven.modrinth:create:UjX6dr61') { transitive = false }
    compileOnly files(createLibs).asFileTree.matching { include '**/*.jar' }
    compileOnly('maven.modrinth:iris:t3ruzodq') { transitive = false }
    compileOnly('maven.modrinth:jei:Tn0dgwL0') { transitive = false }
    testImplementation 'org.ow2.asm:asm-tree:9.8'
    testImplementation 'org.ow2.asm:asm-commons:9.8'
}

tasks.named('test') {
    workingDir layout.buildDirectory.dir('test-work')
    doFirst { workingDir.mkdirs() }
}