resource "cloudflare_zero_trust_tunnel_cloudflared" "main" {
  provider = cloudflare.tunnel

  account_id = var.account_id
  name       = "quorate-main"
  config_src = "cloudflare"

  lifecycle {
    prevent_destroy = true
  }
}

resource "cloudflare_zero_trust_tunnel_cloudflared_config" "main" {
  provider = cloudflare.tunnel

  account_id = var.account_id
  tunnel_id  = cloudflare_zero_trust_tunnel_cloudflared.main.id
  config = {
    ingress = [
      {
        hostname = var.canary_hostname
        service  = var.canary_origin
      },
      {
        hostname = var.mta_sts_hostname
        service  = var.mta_sts_origin
      },
      {
        hostname = var.forge_code_hostname
        service  = var.forge_code_origin
      },
      {
        hostname = "health.quorate.dev"
        service  = "http://cluster-health-api.cluster-health.svc.cluster.local:8080"
      },
      {
        service = "http_status:404"
      },
    ]
  }
}

resource "cloudflare_dns_record" "tier_o_canary" {
  provider = cloudflare.public_dns

  zone_id = var.zone_id
  name    = var.canary_hostname
  type    = "CNAME"
  content = "${cloudflare_zero_trust_tunnel_cloudflared.main.id}.cfargotunnel.com"
  ttl     = 1
  proxied = true
}

resource "cloudflare_dns_record" "mta_sts" {
  provider = cloudflare.public_dns

  zone_id = var.zone_id
  name    = var.mta_sts_hostname
  type    = "CNAME"
  content = "${cloudflare_zero_trust_tunnel_cloudflared.main.id}.cfargotunnel.com"
  ttl     = 1
  proxied = true
}

resource "cloudflare_dns_record" "forge_code" {
  provider = cloudflare.public_dns

  zone_id = var.zone_id
  name    = var.forge_code_hostname
  type    = "CNAME"
  content = "${cloudflare_zero_trust_tunnel_cloudflared.main.id}.cfargotunnel.com"
  ttl     = 1
  proxied = true
}